Spring RTS Engine

Code: Select all

#define HEADING 82 //add to headers, preferably
#define SIG_BUILD 2
StartBuilding(desired_heading)
{
	set-signal-mask SIG_BUILD;
	if (!isbuilding)
	{
		isbuilding = 1;
		
		var speed;
		speed = <90>; //spin, degrees per second, if it's too big and unit often gets stuck in eternal spins, lower the MSperChange

		// radials = spring angle unit
		var current_heading;
		current_heading = (get HEADING);
		
		var MSperChange;
		MSperChange = 40; // milliseconds per cycle of the loop, smaller values for more cpu usage and smoother anim
		
		var RadialsPerChange; //number of radials to increase by every cycle of the loop, calculated from speed
		RadialsPerChange = (MSperChange * speed) / 1000;

		desired_heading = current_heading + desired_heading; // convert local angle into global one
		if (desired_heading > 65535)
		{
			desired_heading = desired_heading - 65536;
		}
		
		if (desired_heading < get HEADING)
		{
			RadialsPerChange = 0 - RadialsPerChange; // make it go the short way rather than all the way around
		}
		
		var headingdiff; //the difference between desired and current headings
		var PosRadialsPerChange; //absolute value
		
		var doneturning;
		while (!doneturning)
		{
			sleep MSPerChange;
			
			set HEADING to ((get HEADING) + RadialsPerChange); //spin unit
			
			PosRadialsPerChange = RadialsPerChange; //get absolute value
			if (RadialsPerChange < 0)
			{
				PosRadialsPerChange = 0 - RadialsPerChange;
			}
			
			headingdiff = (get HEADING) - desired_heading;
			if (headingdiff < 0)
			{
				headingdiff = headingdiff * -1;
			}
			
			if (headingdiff < PosRadialsPerChange) // prevent overshooting, end loop
			{
				set HEADING to desired_heading;
				doneturning = 1;
			}
		}
		
		set INBUILDSTANCE to 1;
	}
}

StopBuilding()
{
	signal SIG_BUILD;
	isbuilding = 0;
 	set INBUILDSTANCE to 0;
}

Code: Select all

#define TURNRATE <8>

StartBuilding(heading, pitch)
{
	signal SIG_Build;
	set-signal-mask SIG_Build;
	
	while(heading <= 0-TURNRATE) {
		set HEADING to (get HEADING)-TURNRATE;
		heading = heading + TURNRATE;
		sleep 30;
	}

	while(heading >= TURNRATE) {
		set HEADING to (get HEADING)+TURNRATE;
		heading = heading - TURNRATE;
		sleep 30;
	}
	
	set INBUILDSTANCE to TRUE;
}

StopBuilding()
{
	signal SIG_BUILD;
	set INBUILDSTANCE to FALSE;
}

Code: Select all

#define TURNRATE <1>
#define HEADING	82

TurnUnit(heading)
	{ 
	while(heading <= 0-TURNRATE)
		{
		set HEADING to (get HEADING)-TURNRATE;
		heading = heading + TURNRATE;
		sleep 30;
	}

	while(heading >= TURNRATE) 
	{
		set HEADING to (get HEADING)+TURNRATE;
		heading = heading - TURNRATE;
		sleep 30;
   }
}
	
QueryNanoPiece(piecenum)
	{
	piecenum = nano;
	}

StartBuilding(heading,pitch)
	{
	signal SIG_AIM4;
	set-signal-mask SIG_AIM4;
	if ( heading > -10923 AND heading < 10923 )
	{
		turn nanobase to y-axis heading speed <90.000000>;
		turn nanoturret to x-axis <0.000000> - pitch speed <50.000000>;
		wait-for-turn nanobase around y-axis;
		wait-for-turn nanoturret around x-axis;
	}
	if ( heading > 10923 )
		{
		heading = heading - 5461;
		call-script TurnUnit(heading);
		turn nanobase to y-axis <30.000000> speed <90.000000>;
		turn nanoturret to x-axis <0.000000> - pitch speed <50.000000>;
		wait-for-turn nanobase around y-axis;
		wait-for-turn nanoturret around x-axis;
		}
	if ( heading < -10923 )
		{
		heading = heading + 5461;
		call-script TurnUnit(heading);
		turn nanobase to y-axis <-30.000000> speed <90.000000>;
		turn nanoturret to x-axis <0.000000> - pitch speed <50.000000>;
		wait-for-turn nanobase around y-axis;
		wait-for-turn nanoturret around x-axis;
		}	
	set INBUILDSTANCE to 1;
	}

StopBuilding()
	{
	set INBUILDSTANCE to 0;
	turn nanobase to y-axis <0.000000> speed <90.000000>;
	turn nanoturret to x-axis <0.000000> speed <50.000000>;
	return (1);
	}

Code: Select all

local body, shovel, nanogun1, nano, nanogun2, nano2, dish = piece ("body", "shovel", "nanogun1", "nano", "nanogun2", "nano2", "dish")

--constants
local SIG_AIM = 2
local SIG_BUILD = 4
local RESTORE_DELAY = 2000
local rad = math.rad
local pi = math.pi

local TURNRATE = 2
local HEADING = 82

--includes
include "rockunit.lua"
include "smokeunit.lua"

function script.Create(unitID)
	turnHack = 1
end

function script.StartBuilding(heading, pitch)
	Signal(SIG_BUILD)
	SetSignalMask(SIG_BUILD)
	originalHeading = GetUnitValue(HEADING)*pi/32768
	
	Turn(body, y_axis, heading*turnHack, TURNRATE)
	Turn(shovel, x_axis, rad(-10), TURNRATE)
	WaitForTurn(body, y_axis)
	
	Turn(body, y_axis, 0)
	Spring.SetUnitRotation(unitID, 0, -(originalHeading+heading), 0 )

	WaitForTurn(shovel, x_axis)
	SetUnitValue(COB.INBUILDSTANCE, 1)
	turnHack = -1
	return 1
end

function script.StopBuilding()
	Signal(SIG_BUILD)
	SetSignalMask(SIG_BUILD)
	SetUnitValue(COB.INBUILDSTANCE, 0)
	Turn(shovel, x_axis, 0, TURNRATE)
	return 0
end

function script.StartMoving()
	turnHack = 1
end
function script.StopMoving()
end

function script.QueryNanoPiece() return nanogun1 end

function script.Killed(recentDamage, maxHealth)
	return 1
end